Away3D-3 含有动画的模型的加载与设置

package 
{
    import away3d.textures.*;
    import away3d.tools.helpers.*;
    import away3d.animators.data.*;
    import away3d.animators.nodes.*;
    import away3d.animators.*;
    import away3d.materials.lightpickers.*;
    import away3d.materials.methods.*;
    import away3d.*;
    import away3d.entities.*;
    import away3d.materials.*;
    import away3d.materials.methods.*;
    import away3d.primitives.*;
    import away3d.utils.*;
    import away3d.containers.*;
    import away3d.tools.commands.*;
    import away3d.events.*;
    import away3d.loaders.*;
    import away3d.loaders.parsers.*;
    import away3d.lights.*;
    import away3d.core.base.*;
    import away3d.cameras.*;
    import away3d.controllers.*;
    import away3d.controllers.*;
    import away3d.primitives.*;
    import away3d.tools.helpers.*;
    import away3d.library.*;
    import away3d.library.assets.*;
    import away3d.animators.data.*;
    import flash.net.*;
    import flash.text.*;

    import flash.display.*;
    import flash.events.*;
    import flash.ui.*;
    import flash.display.*;
    import flash.geom.*;
    import flash.utils.*;
    import flash.filters.*;

    /**
     * ...
     * @author HonmaMeiko
     */
    [SWF(width="600",height="400",backgroundColor="#FFFFFF", frameRate="60")]
    public class Main extends Sprite 
    {
        //3D视图
        private var view:View3D;
        //3D加载器,用于加载模型
        private var loader:Loader3D;
        //骨骼动画集合
        private var animationSet:SkeletonAnimationSet;
        //骨骼动画
        private var animator:SkeletonAnimator;
        //模型网格
        private var modelMesh:Mesh;
        //模型纹理
        private var tex:TextureMaterial;
        
        public function Main()
        {
            view = new View3D();
            //AssetLibrary.enableParser(AWD2Parser); //可以采用这种方式使加载器可以加载AWD2类型的模型文件
            
            //本次模型以及纹理的加载都使用动态加载,动态加载可缩小生成的swf文件的大小
            //首先进行模型的动态加载
            var data:URLLoader = new URLLoader();
            data.dataFormat = URLLoaderDataFormat.BINARY;
            //模型数据加载完成的时候调用监听函数
            data.addEventListener(Event.COMPLETE,OnDownloadComplete);//实际使用的时候第五个参数设置为true以使用弱引用,可以使得监听器在不被使用的时候被GC回收
            data.load(new URLRequest("ceshiyong.awd"));
            //设置camera,指向坐标原点
            view.camera.x = -50;
            view.camera.y = 50;
            view.camera.z = -50;
            view.camera.lookAt(new Vector3D(0,0,0));

            
            stage.addChild(view);
            stage.addEventListener(Event.ENTER_FRAME,OnFrame);
        }
        private function OnDownloadComplete(e:Event):void
        {
            //模型数据动态加载完成的时候为二进制数据,还无法直接使用
            var target:URLLoader = e.target as URLLoader;
            //创建3D加载器
            loader = new Loader3D(false);
            //监听ASSET_COMPLETE事件可以对模型加载的每一步都进行处理,如加载骨骼,加载骨骼位置,加载Mesh等.
            loader.addEventListener(AssetEvent.ASSET_COMPLETE, OnAssetComplete);
            //完全加载完成的时候调用OnAllComplete
            loader.addEventListener(LoaderEvent.RESOURCE_COMPLETE, OnAllComplete);
            //不采用全局解析器的时候可以针对单个3D加载器设置相应的模型解析器
            loader.loadData(target.data, null, null, new AWD2Parser());
            //移除监听器
            target.removeEventListener(Event.COMPLETE, OnDownloadComplete);
        }
        private function OnAssetComplete(event:AssetEvent):void
        {
            //一个模型可以分为多个部分,主要处理的有:骨骼,动画帧节点,网格等.
            if (event.asset.assetType == AssetType.SKELETON) {
                //创建骨骼设置,这里设置的3代表的是网格中的每个顶点都受到3块骨骼的影响.
                animationSet = new SkeletonAnimationSet(3);
                //根据骨骼动画集合创建骨骼动画,而event.asset则包含了骨骼信息
                animator = new SkeletonAnimator(animationSet, event.asset as Skeleton, true);
            } else if (event.asset.assetType == AssetType.ANIMATION_NODE) {
                //获得骨骼动画帧节点
                var animationNode:SkeletonClipNode = event.asset as SkeletonClipNode;
                //将骨骼动画帧节点添加到骨骼动画集中去
                animationSet.addAnimation(animationNode);
            } else if (event.asset.assetType == AssetType.MESH) {
                //获取网格
                var mesh:Mesh = event.asset as Mesh;
                if (mesh) {
                    //判断网格的名字以取得网格,这个名字在建模工具中可以看到
                    if (mesh.name == "ONKBA-Corps-lnew") {
                        modelMesh = mesh;
                    }
                }
            }
        }
        private function OnAllComplete(e:Event):void
        {
            //模型文件完全加载完成以后,移除监听器
            loader.removeEventListener(LoaderEvent.RESOURCE_COMPLETE, OnAllComplete);
            loader.removeEventListener(AssetEvent.ASSET_COMPLETE, OnAssetComplete);
            //设置网格的动画,位置,缩放等属性
            modelMesh.animator = animator;
            modelMesh.x = 0;
            modelMesh.y = 0;
            modelMesh.z = 0;
            modelMesh.scale(0.6);
            //加载完成模型之后开始加载模型的纹理,依旧是动态加载
            var texData:URLLoader = new URLLoader();
            texData.dataFormat = URLLoaderDataFormat.BINARY;
            texData.addEventListener(Event.COMPLETE, OnDownloadTexComplete);
            texData.load(new URLRequest("onkba_N.jpg"));
        }
        private function OnDownloadTexComplete(e:Event):void
        {
            //纹理数据加载完成之后为二进制数据
            var target:URLLoader = e.target as URLLoader;
            //创建加载器,这里是加载纹理图像,因此不是使用Loader3D而是使用Loader
            var texLoader:Loader = new Loader(); 
            //注意添加的是contentLoaderInfo的监听器
            texLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onBitmapComplete);
            //二进制数据在target.data中,使用loadBytes()函数
            texLoader.loadBytes(target.data);
            target.removeEventListener(Event.COMPLETE, OnDownloadTexComplete);
        }
        private function onBitmapComplete(e:Event):void
        {
            //移除监听器
            var target:Loader = LoaderInfo(e.target).loader;
            target.contentLoaderInfo.removeEventListener(Event.COMPLETE, onBitmapComplete);
            //将图像数据转换成纹理材质
            tex = new TextureMaterial(Cast.bitmapTexture(target.content));
            //设置模型网格的材质
            modelMesh.material = tex;
            //设置动画播放速度
            animator.playbackSpeed = 1;
            //开始播放"Run"动画
            animator.play("Run");
            //将网格添加场景中去
            view.scene.addChild(modelMesh);
            //卸载加载器
            target.unload();
        }
        private function OnFrame(e:Event):void
        {
            //渲染
            view.render();
        }
    }
}

AssetLibrary.enableParser(AWD2Parser); //可以采用这种方式使所有加载器都可以加载AWD2类型的模型文件
loader.loadData(target.data, null, null, new AWD2Parser());
以上是两种使用3D模型解析器的方式.动态加载文件主要是两步:

1.使用URLLoader加载文件,在监听事件中监听Event.COMPLETE事件
2.在完成事件函数中,使用Loader3D或Loader完成数据的加载(其实是对二进制数据的解析).

在模型和纹理都加载完成之后即可添加到场景中.

骨骼动画说明:
从3DSMAX中导出AWD模型需要使用插件,可到Away3D下载.
导出时选项设置:
1.General栏
Compression 设置成GZIP,压缩可使模型更小.
Export custom attribute 去掉勾选状态,不用设置

2.Scene&geometry栏
全部勾选
并注意最下面的Joints per vertex,这里设置成3表示每个顶点受到3块骨骼的影响.这个值不一定要设置成3(这里只是个例子).
注意,这里填的数值就是创建骨骼动画集的时候设置的参数!两处一定要设置成一样的.
animationSet = new SkeletonAnimationSet(3);

3.Material栏
勾选Include Material,表示包含材质.
(1).绝对路径,最好不要使用
(2).相对路径,可以勾选复制纹理到模型保存的目录(我测试的时候貌似没有效果,所以我没有勾选)
(3).将纹理包含到模型文件中,含义就是纹理图片包含在模型里面了(我没注意这个怎么使用)

4.Animation栏
(1).包含骨骼,骨骼动画模型必备
(2.)包含动画序列
就是按帧数分割动画,本例中使用的sequences.txt如下:

Breathe 0 60
Walk 70 130
Run 140 157

格式:

动画名 起始帧数 终止帧数

sequences.txt文件需要在导出之前就保存在导出目录中

模型导入后动画的使用方法:

animator.play("Run");

5.Flash viewer栏
导出后自动生成swf和html文件,用以预览模型(我测试时看到模型但看不到贴图)