在纯AS工程中嵌入个别字体方法

2009-11-26 10:00

前两天接到主管任务，让研究在纯AS工程中嵌入个别字体。在网上找了一大通，也只找到了在Flex项目中使用CSS也嵌入个别字体的方法。最后很无奈的发现网上好像没有我想找的资料。就在此时让我有个想法，在CSS中控制嵌入字体使用的是unicodeRange属性，那我能不能在Embed标签中也使用它呢？实验发现，Embed标签中是可以使用unicodeRange属性的。下面说说我在纯AS工程中是怎么嵌入个别字体的。

工程开始之前先告诉大家，我要嵌入的字符是"空山无人，水流花开。"，要使用的字体是楷体字;

1.打包要嵌入字体到一个Swf文件中

(1).新建一个纯AS工程，内容如下：

package {
 import flash.display.Sprite;
 import flash.system.Security;
 import flash.text.Font;

 public class LoadFont extends Sprite
{
   [Embed(source="C:/WINDOWS/Fonts/SIMKAI.TTF",fontName="kai",mimeType="application/x-font",unicodeRange="U+7a7a,U+5c71,U+65e0,U+4eba,U+ff0c,U+6c34,U+6d41,U+82b1,U+5f00,U+3002")]
        public var RoundHand:Class;
        
   public function LoadFont()
   {
   }
}
}

其中，source的值就是字符所在位置（控制面板--字体--楷体，点右键就可以看到其所在位置），

fontName的值就是该字体名称，只要确保唯一，可随意起。

mimeType的值照抄。

unicodeRange的值就是"空山无人，水流花开。"，这几个字对应的unicode

RoundHand就是该字体绑定的类，也是唯一的。

工程建好后编译，会在bin-debug目录下生成一个名为LoadFont.swf文件。

2.在工程中使用字体

在自己的工程中想要使用该字体，先要用下一段：

 

 

fontLoader = new Loader();
    fontLoader.load(new URLRequest("LoadFont.swf的路径"), new LoaderContext(false, loaderInfo.applicationDomain));
    fontLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);

private function completeHandler(e:Event):void 
   {
    fontLoader.contentLoaderInfo.removeEventListener(Event.COMPLETE, completeHandler);
    fontLoader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    var MyFont:Class = getDefinitionByName("LoadFont_RoundHand") as Class;
    // 注册全局字体
    Font.registerFont(MyFont); 
    var myFont:Font = new MyFont() as Font;
    // 应用字体
    var format:TextFormat = new TextFormat(myFont.fontName, 25, null, true);
    txt.defaultTextFormat = format;
    // 嵌入字体
    txt.embedFonts = true;
    txt.text = "空山无人，水流花开。";
   }

其中注意getDefinitionByName的参数格式为“所在类名+"_"+embed的类名”。
 

 

整个工程如下：

package 
{
import flash.display.Loader;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.net.URLRequest;
import flash.system.LoaderContext;
import flash.text.Font;
import flash.text.TextField;
import flash.text.TextFormat;
import flash.utils.getDefinitionByName;

public class FontTest extends Sprite 
{
   private var txt:TextField;
   private var fontLoader:Loader;
   public function FontTest():void 
   {
    if(stage!=null){
     init();
    }else{
     addEventListener(Event.ADDED_TO_STAGE,init);
    }
   }
   private function init():void{
    stage.quality = StageQuality.HIGH;
    stage.scaleMode = StageScaleMode.NO_SCALE;
    stage.align = StageAlign.TOP_LEFT;
    stage.showDefaultContextMenu = false;
   
    txt = new TextField();
    txt.x = stage.stageWidth/3;
    txt.y = stage.stageHeight/2;
    txt.width = 500;
    txt.height = 30;
    addChild(txt);
   
    fontLoader = new Loader();
    fontLoader.load(new URLRequest("LoadFont.swf"), new LoaderContext(false, loaderInfo.applicationDomain));
    fontLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
    fontLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);
   }
   private function progressHandler(e:ProgressEvent):void 
   {
    var ratio:int = e.bytesLoaded / e.bytesTotal * 100;
    txt.text = "loading... " + ratio + "%";
   }
  
   private function completeHandler(e:Event):void 
   {
    fontLoader.contentLoaderInfo.removeEventListener(Event.COMPLETE, completeHandler);
    fontLoader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    var MyFont:Class = getDefinitionByName("LoadFont_RoundHand") as Class;
    // 注册全局字体
    Font.registerFont(MyFont); 
    var myFont:Font = new MyFont() as Font;
    // 应用字体
    var format:TextFormat = new TextFormat(myFont.fontName, 25, null, true);
    txt.defaultTextFormat = format;
    // 嵌入字体
    txt.embedFonts = true;
    txt.text = "空山无人，水流花开。";
   }
}
}