Inno_Setup使用笔记（简单完成安装包制作）

（若水三千只取一瓢，技艺纷繁千森取叶）

版本：5.5.9

流程：1、将要打包文件整理好，最好整理成客户最后安装完成样式，方便路径编写。

　　　2、在目录下建一个脚本文件（*.iss）（位置随意，但建在目录文件方便写路径代码）。

　　　3、完成脚本文件后在其编译器（Inno Setup Compiler）中编译，完成安装文件制作。

说明：脚本文件中注释采用 ; 进行标识，只能在行首，行中不识别。

　　   本例对应IDE软件，需要注册对应文件类型链接

举例说明：

/-----------------------------------------------------------------------------------/
;需要变更内容采用宏形式定义，方便更改
#include MyAppname "My_IDE"
[Setup]
;部分内容将成为安装文件属性，部分会打印在安装界面
; 注: AppId的值为单独标识该应用程序。
; 不要为其他安装程序使用相同的AppId值。
; (生成新的GUID，点击 工具|在IDE中生成GUID。)
AppId={{A9861883-31C5-4324-BD9A-DC3271EEB675}
;程序名 宏定义使用方式需要{}加#实现
AppName={#MyAppname}
;版本号
AppVerName=ISsample 1.0.0.0
;发布者名
AppPublisher=Hkiss
;相关连接
AppPublisherURL=http://zwkufo.blog.163.com
AppSupportURL=http://zwkufo.blog.163.com
AppUpdatesURL=http://zwkufo.blog.163.com
;默认安装目录 默认地址可以客户手动更改 {pf}表示程序文件地址一般为：C:\Program Files
DefaultDirName={pf}\ISsample
;默认开始菜单名 开始菜单中创建文件夹的名称
DefaultGroupName=ISsample
;是否打开->可选安装开始菜单项
;AllowNoIcons=yes
;安装协议 可选
;LicenseFile=C:\Example\原始文件\agreement.txt
;安装前查看的文本文件
;InfoBeforeFile=C:\Example\原始文件\Setup_New.txt
;安装后查看文本文件
;InfoAfterFile=C:\Example\原始文件\Setup_Old.txt
;输出文件夹 EXE文件导出地址
OutputDir=C:\Example\InnoSetup\out
;输出文件名
OutputBaseFilename=setup
;安装图标 安装文件的图标
SetupIconFile=C:\Example\原始文件\title.ico
;安装需要输入密码
;Password=123
;Encryption=yes
;压缩相关
Compression=lzma
SolidCompression=yes
;备注版本信息
;安装器文件说明
VersionInfoDescription=ISsample 汉化增强版
;安装器版本号
VersionInfoVersion=1.0.0.0
;查找注册表应用程序安装地址和开始菜单地址
UsePreviousAppdir = no
UsePreviousGroup = no

;制作选择语言
[Languages]
;语言类型；语言文件地址
Name: "chs"; MessagesFile: "compiler:Default.isl" 
Name: "en"; MessagesFile: "compiler:Languages\English.isl"

;用户定制任务
[Tasks]
;桌面快捷方式;　　　　　 任务描述：创建桌面快捷方式;　　　　　　　　　　 任务组描述：额外的图标;额外选项：　　　　　　　　  非选择（默认选项）;　允许windows版本：0~6.1
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked; OnlyBelowVersion:0,6.1
;快捷启动快捷方式
Name: "quicklaunchicon"; Description: "{cm:CreateQuickLaunchIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

;文件安装
[Files]
;用户定义组件安装
;原始地址 ;打包地址 ;文件及子文件夹
Source: "C:\Example\原始文件\Components\Components_1.txt"; DestDir: "{app}\Components"; Flags: ignoreversion recursesubdirs createallsubdirs
;脚本地址目录
Source: ".\原始文件\Components\Components_2.txt"; DestDir: "{app}\Components"; Flags:ignoreversion recursesubdirs createallsubdirs
Source: "C:\Example\原始文件\Components\Components_3.txt"; DestDir: "{app}\Components"; Flags: ignoreversion recursesubdirs createallsubdirs

;注册表操作;文件关联
[Registry]
;HKCR:根键:保存文件类型，文件关联 ;子键：后缀名为.jhp ;值类型:字符串 ;键值:关联文件名 ;额外选项:卸载程序删除注册表
Root: HKCR; Subkey: ".c"; ValueType: String; ValueData: "c_file";Flags: uninsdeletekey
;关联文件名 关联 关联文件类型（属性）
Root: HKCR; Subkey: "c_file"; ValueType: String; ValueData: "c_file";Flags: uninsdeletekey
;关联文件图标
Root: HKCR; Subkey: "c_file\DefaultIcon";String; ValueData: "{app}\Common\MSDev98\123.ico";Flags: uninsdeletekey
;关联文件启动程序地址
Root: HKCR; Subkey: "c_file\shell\open\command"; ValueType: String; ValueData: "{app}\Common\MSDev98\Bin\msdev.exe ""%1""";Flags: uninsdeletekey


;开始菜单，桌面快捷方式
[Icons]
;快捷方式地址 ;源地址
;开始菜单快捷
Name: "{group}\ISsample"; Filename: "{app}\ISsample.exe"
Name: "{group}\{cm:ProgramOnTheWeb,ISsample}"; Filename: "http://zwkufo.blog.163.com"
Name: "{group}\{cm:UninstallProgram,ISsample}"; Filename: "{uninstallexe}"
;Tasks 匹配快捷
;桌面快捷
Name: "{commondesktop}\ISsample"; Filename: "{app}\ISsample.exe"; Tasks: desktopicon
;快速启动快捷
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\ISsample"; Filename: "{app}\ISsample.exe"; Tasks: quicklaunchicon

;用来在程序安装完成后 在安装程序显示最终对话框之前执行程序 常用与运行主程序 显示自述文件 删除临时文件
[Run]
;驱动地址　　;是否安装驱动　　　;处理下一步时不等待该步完成是否，安装完成界面创建选择框
Filename: "{app}\ISsample.exe"; Description: "安装驱动程序"; Flags: nowait postinstall 
;显示说明文件  　　;处理下一步时不等待该步完成是否，安装完成界面创建选择框 非.exe或.com标记
Filename: "{app}\ISsample.txt"; Description: "查看显示自述文件"; Flags: postinstall skipifsilent shellexec