（实模式+保护模式）模式切换的过程步骤（代码+文字解析）

【0】写在前面

文末的个人总结是干货，前面代码仅供参考的，且source code from orange’s implemention of a os.

; ==========================================
; pmtest2.asm
; 编译方法：nasm pmtest2.asm -o pmtest2.com
; ==========================================

%include    "pm.inc"    ; 常量, 宏, 以及一些说明

 org    0100h
 jmp    LABEL_BEGIN

；全局描述符表定义
[SECTION .gdt]

; GDT
;                            段基址,        段界限 , 属性
    LABEL_GDT:         Descriptor    0,              0, 0         ; 空描述符
    LABEL_DESC_NORMAL: Descriptor    0,         0ffffh, DA_DRW    ; Normal 描述符
    LABEL_DESC_CODE32: Descriptor    0, SegCode32Len-1, DA_C+DA_32; 非一致代码段, 32
    LABEL_DESC_CODE16: Descriptor    0,         0ffffh, DA_C      ; 非一致代码段, 16
    LABEL_DESC_DATA:   Descriptor    0,      DataLen-1, DA_DRW    ; Data
    LABEL_DESC_STACK:  Descriptor    0,     TopOfStack, DA_DRWA+DA_32; Stack, 32 位
    LABEL_DESC_TEST:   Descriptor 0500000h,     0ffffh, DA_DRW
    LABEL_DESC_VIDEO:  Descriptor  0B8000h,     0ffffh, DA_DRW    ; 显存首地址
; GDT 结束

GdtLen   equ    $ - LABEL_GDT  ; GDT长度
GdtPtr   dw GdtLen - 1  ; GDT界限
  dd    0    ; GDT基地址

;GDT 选择子定义

SelectorNormal   equ    LABEL_DESC_NORMAL   - LABEL_GDT
SelectorCode32   equ    LABEL_DESC_CODE32   - LABEL_GDT
SelectorCode16   equ    LABEL_DESC_CODE16   - LABEL_GDT
SelectorData     equ    LABEL_DESC_DATA  - LABEL_GDT
SelectorStack    equ    LABEL_DESC_STACK    - LABEL_GDT
SelectorTest     equ    LABEL_DESC_TEST  - LABEL_GDT
SelectorVideo    equ    LABEL_DESC_VIDEO    - LABEL_GDT

; END of [SECTION .gdt]

;数据段定义
[SECTION .data1] ; 数据段

ALIGN   32
[BITS   32]
LABEL_DATA:
SPValueInRealMode   dw  0
; 字符串
PMMessage:   db "In Protect Mode now. ^-^", 0   ; 在保护模式中显示 ;Mine【后面的零作为字符串的结束标志，Line189、232的test会用到】
    OffsetPMMessage  equ    PMMessage - $$  ; Mine【$$ == LABEL_DATA 的基地址，相对于 LABEL_DATA 的偏移地址】
    StrTest:     db "ABCDEFGHIJKLMNOPQRSTUVWXYZ", 0   ;Mine【后面的零作为字符串的结束标志】
OffsetStrTest    equ    StrTest - $$
DataLen  equ    $ - LABEL_DATA

; END of [SECTION .data1]

；全局堆栈段
[SECTION .gs]

ALIGN   32
[BITS   32]
LABEL_STACK:
times 512 db 0
TopOfStack  equ $ - LABEL_STACK - 1

; END of [SECTION .gs]

；16位代码段， CPU运行在实模式下，为什么只有在16位代码段下才能修改GDT中的值；
[SECTION .s16] ; Mine【为从实模式跳转到保护模式所做的准备工作】

[BITS   16]
LABEL_BEGIN:
 mov    ax, cs
 mov    ds, ax
 mov    es, ax
 mov    ss, ax
 mov    sp, 0100h

; 下一行指令的解说：
; 待会要跳回到实模式，这里是保存跳转前的相关 value
; mov [label_backto_real + 3], ax, 这是在代码已经加载到了内存之后再执行的，为什么加上3，一位jmp指令占用3个字节，而jmp后面跟着跳转地址；
; 他的作用是在段基地址存储单元中去重新设置新值去覆盖原先的段基地址，作者真心很是聪明啊。

 mov    [LABEL_GO_BACK_TO_REAL+3], ax
 mov    [SPValueInRealMode], sp      ; Mine【保存sp，然后返回实模式后，再将sp取出来】

；初始化 16 位代码段描述符

 mov    ax, cs
 movzx  eax, ax
 shl    eax, 4
 add    eax, LABEL_SEG_CODE16
 mov    word [LABEL_DESC_CODE16 + 2], ax
 shr    eax, 16
 mov    byte [LABEL_DESC_CODE16 + 4], al
 mov    byte [LABEL_DESC_CODE16 + 7], ah

；初始化 32 位代码段描述符

 xor    eax, eax
 mov    ax, cs
 shl    eax, 4
 add    eax, LABEL_SEG_CODE32
 mov    word [LABEL_DESC_CODE32 + 2], ax
 shr    eax, 16
 mov    byte [LABEL_DESC_CODE32 + 4], al
 mov    byte [LABEL_DESC_CODE32 + 7], ah

；初始化数据段描述符

 xor    eax, eax
 mov    ax, ds
 shl    eax, 4
 add    eax, LABEL_DATA        ; Mine【数据段的基址便是 LABEL_DATA 的物理地址 
                                          ; 所以 OffsetStrTest 既是字符串相对于 LABEL_DATA 的偏移地址，也是其在数据段的偏移 】
 mov    word [LABEL_DESC_DATA + 2], ax
 shr    eax, 16
 mov    byte [LABEL_DESC_DATA + 4], al
 mov    byte [LABEL_DESC_DATA + 7], ah

；初始化堆栈段描述符

 xor    eax, eax
 mov    ax, ds
 shl    eax, 4
 add    eax, LABEL_STACK
 mov    word [LABEL_DESC_STACK + 2], ax
 shr    eax, 16
 mov    byte [LABEL_DESC_STACK + 4], al
 mov    byte [LABEL_DESC_STACK + 7], ah

; 为加载 GDTR 作准备，填充GDT基地址的数据结构

 xor    eax, eax
 mov    ax, ds
 shl    eax, 4
 add    eax, LABEL_GDT   ; eax <- gdt 基地址
 mov    dword [GdtPtr + 2], eax ; [GdtPtr + 2] <- gdt 基地址

; 加载 GDTR

 lgdt   [GdtPtr]

; 关中断

cli

; 打开地址线A20

 in al, 92h
 or al, 00000010b
 out    92h, al

; 准备切换到保护模式， PE位置1

 mov    eax, cr0
 or eax, 1
 mov    cr0, eax

; 真正进入保护模式

 jmp    dword SelectorCode32:0  ; 执行这一句会把 SelectorCode32 装入 cs, 并跳转到 Code32Selector:0  处

; 从保护模式跳回到实模式就到了这里（注意：从保护模式跳转到实模式，即本标识符下，本标识符是存在于初始化描述符的16位代码段的末尾的）

LABEL_REAL_ENTRY: 
 mov    ax, cs
 mov    ds, ax
 mov    es, ax
 mov    ss, ax

 mov    sp, [SPValueInRealMode]

; 关闭 A20 地址线

 in al, 92h  ; 
 and    al, 11111101b 
 out    92h, al  ; /

 sti     ; 开中断

 mov    ax, 4c00h   ; `.
 int    21h  ; /  回到 DOS

; END of [SECTION .s16]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; 32 位代码段. 由实模式跳入
[SECTION .s32]

[BITS   32]

LABEL_SEG_CODE32:
 mov    ax, SelectorData
 mov    ds, ax   ; 数据段选择子
 mov    ax, SelectorTest
 mov    es, ax   ; 测试段选择子
 mov    ax, SelectorVideo
 mov    gs, ax   ; 视频段选择子

 mov    ax, SelectorStack        ; Mine【改变了ss和esp， 则在32位代码段中所有的堆栈操作将会在新增的堆栈段中进行】
 mov    ss, ax   ; 堆栈段选择子

 mov    esp, TopOfStack

; 下面显示一个字符串（此处代码有省略）

 mov    ah, 0Ch  ; 0000: 黑底    1100: 红字
 xor    esi, esi
 xor    edi, edi
 mov    esi, OffsetPMMessage    ; 源数据偏移
 mov    edi, (80 * 10 + 0) * 2  ; 目的数据偏移。屏幕第 10 行, 第 0 列。
 cld
.1:
 lodsb    ; Mine【lodsb、lodsw：把DS:SI指向的存储单元中的数据装入AL或AX，然后根据DF标志增减SI】
 test   al, al  ; Mine【1. test ax，100b  将 ax的 值  和 100b进行“与”操作 ，但不改变ax本身
     ; 2. 若与操作的结果为零则ZF置位】
 jz .2
 mov    [gs:edi], ax
 add    edi, 2
 jmp    .1
.2: ; 显示完毕

 call   DispReturn ; Mine【call == push ip ; jmp near ptr 标号】

 call   TestRead    ; Mine【先读出数据】
 call   TestWrite   ; Mine【再写入数据】
 call   TestRead    ; Mine【再次读出数据】

; 到此停止，跳入16位代码段

 jmp    SelectorCode16:0     ; Mine【Line31，Line80 已经初始化LABEL_DESC_CODE16，保存着LABEL_SEG_CODE16的基地址 】

SegCode32Len    equ $ - LABEL_SEG_CODE32

; END of [SECTION .s32]

; 16 位代码段. 由 32 位代码段跳入, 跳出后到实模式(LABEL_REAL_ENTRY)
[SECTION .s16code]

ALIGN   32
[BITS   16]
LABEL_SEG_CODE16:

; 跳回实模式:

 mov    ax, SelectorNormal      ; Mine【 选择子 SelectorNormal 是对描述符 LABEL_DESC_NORMAL 的索引 】
 mov    ds, ax
 mov    es, ax
 mov    fs, ax
 mov    gs, ax
 mov    ss, ax

 mov    eax, cr0
 and    al, 11111110b     ; Mine【cr0的最后一位PE位置为0，进入实模式】
 mov    cr0, eax

LABEL_GO_BACK_TO_REAL:
 jmp    0:LABEL_REAL_ENTRY     ; 段地址会在程序开始处被设置成正确的值

Code16Len   equ $ - LABEL_SEG_CODE16

; END of [SECTION .s16code]

总结：（从实模式》》保护模式》》实模式）模式切换的过程步骤：（干货）

（Attention：我们依照程序执行过程的跳转步骤来对内存内容进行解析）

（1） org 0100，告诉编译器程序运行时，要加载到偏移地址0100处；jmp LABEL_BEGIN 跳入到16位代码段（实模式）进行各个数据段，代码段，堆栈段的初始化，最后跳入到保护模式；

（2）GDT初始化（定义段描述符 + 定义GDTR的数据结构 + 定义GDT选择子）：

2.1）定义全局描述符表GDT表项，即定义需要的段描述符，数据段和代码段描述符数据结构如下：
2.2）定义GDTR全局描述符的数据结构并赋值，GDTR的数据结构如下：
2.3）定义GDT选择子：有多少个描述符表项，就有多少个选择子，选择子用于记录描述符相对于GDT基地址的偏移地址，因为GDT的基地址和界限是保存在全局描述符寄存器GDTR中的，我们可以通过GDTR找到GDT基地址，然后通过选择子找到对应的偏移地址，从而找到对应的段描述符的基地址+界限（偏移量）+属性，而描述符基地址的值又记录了各个代码段或数据段的基地址，这样我们就可以通过选择子来索引到具体的代码段和数据段；

（3）数据段 + 堆栈段的定义

（4）16位代码段（实模式下）的定义：

4.1）设置代码运行环境，即给相关寄存器赋值；
4.2）初始化16位代码段描述符 + 32位代码段描述符 + 堆栈段描述符 +数据段描述符；
4.3）初始化全局描述符表寄存器GDTR的内容，因为其基地址还没有初始化，然后通过lgdt [GdtPtr]，将内存中GDTR的内容加载到GDTR中，重点在于保存 GDT的基地址；
4.4）关中断，即设置CPU不响应任何其他的外部中断，因为CPU现在的时间片只属于当前加载的程序；
4.5）打开地址线A20；至于为什么要打开，呵呵，参见：http://blog.csdn.net/pacosonswjtu/article/details/48005813
4.6）将CR0的 PE 位置1；PE位==1，表明CPU运行在保护模式下；（这是准备切换到保护模式阶段），CR0的数据结构如下：
4.7）跳转到保护模式： jmp dword SelectorCode32:0 ，这里的代码指提供了选择子，（2.3）末部分，已经说明了为什么通过选择子就可以索引到 32位代码段 LABEL_SEG_CODE32；（这就是从实模式跳入保护模式）

（5）32位代码段（由实模式跳入，即保护模式）的定义

5.1）将对应选择子赋值到对应寄存器，即设置任务代码的运行环境，不得不提的是本段代码还改变了ss和esp，则在32位代码段中所有的堆栈操作将会在新增的堆栈段中进行；
5.2）做任务，我们这里是打印一串字符串；
5.3）任务做完后，跳转到16位代码段，因为从保护模式跳回实模式，只能从16位代码段中跳回；（这个，到底是因为什么，我也说不清楚）

（6）调回到实模式的16位代码段（我们干脆叫它为过渡的16位代码段，与模块（4）做个区别）

6.1）加载一个描述符选择子，说是要实现从32位代码段返回时cs 高速缓冲寄存器中的属性符合实模式的要求，（具体的，我这里也没有懂）
6.2）将CR0的 PE 位置0；PE位==0，表明CPU运行在实模式下；（这是准备切换到实模式阶段），参见4.6所附图片；
6.3）真正跳转到实模式：LABEL_GO_BACK_TO_REAL: jmp 0:LABEL_REAL_ENTRY ; 这里的0 纯粹是个幌子，我理解的是，它就是个占位符而已，因为在16位代码段初始化的时候，已经将它的值设定为跳转前的 cs（段基址）值了，即 mov [LABEL_GO_BACK_TO_REAL+3], ax；

【7】跳回到16位代码段（实模式）的定义

7.1）该段代码定义在（5）代码区域的末尾，因为，它们都是实模式下的运行环境；
7.2）初始化寄存器的值，设置运行环境；
7.3）重新设置堆栈指针sp 的值，这个值早在16位代码段初始化的时候，已经将它的值暂存在变量里了，这里只是将它恢复到原来的值而已，即 mov [SPValueInRealMode], sp；
7.4）关闭A20地址线，为什么要关闭，参见：http://blog.csdn.net/pacosonswjtu/article/details/48005813
7.5）开中断；
7.6）产生中断信号，回到DOS；

posted @ 2015-08-26 20:03 PacosonSWJTU 阅读(2347) 评论(0) 编辑收藏举报

会员力量，点亮园子希望

刷新页面返回顶部

技术分享，互惠你我！wish to make progress with everyone.

技术分享，互惠你我！wish to make progress with everyone.

（实模式+保护模式）模式切换的过程步骤（代码+文字解析）

【0】写在前面

文末的个人总结是干货，前面代码仅供参考的，且source code from orange’s implemention of a os.

总结：（从实模式》》保护模式》》实模式）模式切换的过程步骤：（干货）

（Attention：我们依照程序执行过程的跳转步骤来对内存内容进行解析）

（1） org 0100，告诉编译器程序运行时，要加载到偏移地址0100处；jmp LABEL_BEGIN 跳入到16位代码段（实模式）进行各个数据段，代码段，堆栈段的初始化，最后跳入到保护模式；

（2）GDT初始化（定义段描述符 + 定义GDTR的数据结构 + 定义GDT选择子）：

（3）数据段 + 堆栈段的定义

（4）16位代码段（实模式下）的定义：

（5）32位代码段（由实模式跳入，即保护模式）的定义

（6）调回到实模式的16位代码段（我们干脆叫它为过渡的16位代码段，与模块（4）做个区别）

【7】跳回到16位代码段（实模式）的定义

技术分享，互惠你我！wish to make progress with everyone.

技术分享，互惠你我！wish to make progress with everyone.

（实模式+保护模式）模式切换的过程步骤（代码+文字解析）

【0】写在前面

文末的个人总结是干货，前面代码仅供参考的，且source code from orange’s implemention of a os.

总结： （从实模式》》保护模式》》实模式）模式切换的过程步骤：（干货）

（Attention：我们依照程序执行过程的跳转步骤来对内存内容进行解析）

（1） org 0100， 告诉编译器程序运行时，要加载到偏移地址0100处；jmp LABEL_BEGIN 跳入到16位代码段（实模式）进行各个数据段，代码段，堆栈段的初始化，最后跳入到保护模式；

（2）GDT初始化（定义段描述符 + 定义GDTR的数据结构 + 定义GDT选择子）：

（3）数据段 + 堆栈段的定义

（4）16位代码段（实模式下）的定义：

（5）32位代码段（由实模式跳入，即保护模式）的定义

（6）调回到实模式的16位代码段（我们干脆叫它为过渡的16位代码段， 与模块（4）做个区别）

【7】跳回到16位代码段（实模式）的定义

总结：（从实模式》》保护模式》》实模式）模式切换的过程步骤：（干货）

（1） org 0100，告诉编译器程序运行时，要加载到偏移地址0100处；jmp LABEL_BEGIN 跳入到16位代码段（实模式）进行各个数据段，代码段，堆栈段的初始化，最后跳入到保护模式；

（6）调回到实模式的16位代码段（我们干脆叫它为过渡的16位代码段，与模块（4）做个区别）