关于SQL编程中数组的解决方法

-- =============================================
--对象:  function [dbo].[Fn_LGZ_Get_StrArrayLength]   
--功能描述:按指定符号分割字符串，返回分割后的元素个数，方法很简单，
                --就是看字符串中存在多少个分隔符号，然后再减一，就是要求的结果。
--作   者：

--创建时间：2008-3-24

--调用示例：select dbo.Fn_LGZ_Get_StrArrayLength('78,1,2,3',',')
--返回值：4
-- =============================================
CREATE function [dbo].[Fn_LGZ_Get_StrArrayLength]
(
@str varchar(1024),  --要分割的字符串
@split varchar(10)  --分隔符号
)
returns int
as
begin
declare @location int
declare @start int
declare @length int

set @str=ltrim(rtrim(@str))
set @location=charindex(@split,@str)
set @length=1
while @location<>0
begin
   set @start=@location+1
   set @location=charindex(@split,@str,@start)
   set @length=@length+1
end
return @length
end

 

-- =============================================
--对象:  Fn_LGZ_Get_StrArrayStrOfIndex   
--功能描述：按指定符号分割字符串，返回分割后指定索引的第几个元素，象数组一样方便  索引从一开始
--作   者：

--创建时间：2008-3-23
--调用：SELECT [Analytics_DW_AD].[dbo].[Fn_LGZ_Get_StrArrayStrOfIndex] ('78,1,2,3',',',1)
--返回值：78
-- =============================================
CREATE  function [dbo].[Fn_LGZ_Get_StrArrayStrOfIndex]
(
@str varchar(1024),  --要分割的字符串
@split varchar(10),  --分隔符号
@index int --取第几个元素
)
returns varchar(1024)
as
begin
declare @location int
declare @start int
declare @next int
declare @seed int

set @str=ltrim(rtrim(@str))
set @start=1
set @next=1
set @seed=len(@split)

set @location=charindex(@split,@str)
while @location<>0 and @index>@next
begin
   set @start=@location+@seed
   set @location=charindex(@split,@str,@start)
   set @next=@next+1
end
if @location =0 select @location =len(@str)+1
--这儿存在两种情况：1、字符串不存在分隔符号 2、字符串中存在分隔符号，
--跳出while循环后，@location为0，那默认为字符串后边有一个分隔符号。

return substring(@str,@start,@location-@start)
end