动态加载内嵌类库文件的方法

有时候我们引用了一个小型的类库文件,但是如果发布程序,就需要带一个类库文件,感觉有点累赘,那该怎么办?
一些第三方的混淆工具自带类库集成,是一个不错的解决办法。
但是如果我只想使用自己的解决方法,那么可以尝试将类库文件以资源嵌入的方式,集成入程序集内!

但是我在测试这个办法的时候,经常会发现程序无法正确加载类库。
如下面的代码,实际上每次在执行时都会发生错误:

Sub Main()

    Dim dllName As String = "程序命名空间.类库文件.dll"
    Dim dllStream As IO.Stream = Reflection.Assembly.GetEntryAssembly.GetManifestResourceStream(dllName)

    Dim dllbytes(dllStream.Length - 1) As Byte
    dllStream.Read(dllbytes, 0, dllStream.Length)
    dllStream.Close()

    Reflection.Assembly.Load(dllbytes)

    Application.EnableVisualStyles()
    Application.Run(New Main)

End Sub

 

当执行以上代码,程序可以正确加载位于程序集内部的类库文件,在启动时不会发生任何错误。
但是当我们在窗体内执行类库内的代码,就会发生无法引用类库的错误。
究竟错在了哪里?让我百思不得其解。


后来我google了一下问题原因,发现.NET程序并不是在使用时才开始解析并生成本地代码,而是在之前就已经生成了各种对象的引用指针。
但是在引用时,如果发现对象并不存在,则会引发一个 AppDomain.AssemblyResolve 事件,因此可以通过 AssemblyResolve 来在发生类库引用错误时,动态地返回类库程序集实例。

所以我们只需要将加载事件改动到 AssemblyResolve 中就可以了。

Sub main()
    AddHandler AppDomain.CurrentDomain.AssemblyResolve, AddressOf assresolve

    Application.EnableVisualStyles()
    Application.Run(New Form1)
End Sub

Private Function assresolve(ByVal sender As Object, ByVal args As ResolveEventArgs) As Assembly
    Dim aName As String = New Reflection.AssemblyName(args.Name).FullName
    If aName = "类库完整描述名" Then
        Dim dllName As String = "程序命名空间.类库文件.dll"
        Dim dllStream As IO.Stream = Reflection.Assembly.GetEntryAssembly.GetManifestResourceStream(dllName)
        Dim dllbytes(dllStream.Length - 1) As Byte
        dllStream.Read(dllbytes, 0, dllStream.Length)
        dllStream.Close()
        Return Reflection.Assembly.Load(dllbytes)
    End If

    Return Nothing
End Function

这样,当加载类库发生错误之时,就会自动的加载内嵌的DLL文件到程序中。

posted @ 2017-03-02 00:43 二笔青年 阅读(...) 评论(...) 编辑 收藏